Browse code

First commit

Qurban Ullah authored on 27/02/2018 17:47:58
Showing 2 changed files
1 1
new file mode 100755
... ...
@@ -0,0 +1,46 @@
1
+pkgbase = dbus-selinux
2
+	pkgdesc = Freedesktop.org message bus system with SELinux support
3
+	pkgver = 1.10.8
4
+	pkgrel = 1
5
+	url = http://www.freedesktop.org/Software/dbus
6
+	arch = i686
7
+	arch = x86_64
8
+	groups = selinux
9
+	license = GPL
10
+	license = custom
11
+	makedepends = libx11
12
+	makedepends = systemd-selinux
13
+	makedepends = xmlto
14
+	makedepends = docbook-xsl
15
+	makedepends = audit
16
+	makedepends = libselinux
17
+	source = http://dbus.freedesktop.org/releases/dbus/dbus-1.10.8.tar.gz
18
+	source = http://dbus.freedesktop.org/releases/dbus/dbus-1.10.8.tar.gz.asc
19
+	validpgpkeys = DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90
20
+	validpgpkeys = 3C8672A0F49637FE064AC30F52A43A1E4B77B059
21
+	md5sums = e912e930f249454752512aa7ac864d43
22
+	md5sums = SKIP
23
+
24
+pkgname = dbus-selinux
25
+	depends = libdbus-selinux
26
+	depends = expat
27
+	depends = audit
28
+	depends = libselinux
29
+	depends = libsystemd-selinux
30
+	optdepends = libx11: dbus-launch support
31
+	provides = dbus-core
32
+	provides = dbus=1.10.8-1
33
+	provides = selinux-dbus=1.10.8-1
34
+	conflicts = dbus-core
35
+	conflicts = dbus
36
+	conflicts = selinux-dbus
37
+	replaces = dbus-core
38
+	replaces = dbus
39
+
40
+pkgname = libdbus-selinux
41
+	pkgdesc = DBus library
42
+	depends = libsystemd-selinux
43
+	provides = libdbus=1.10.8-1
44
+	conflicts = libdbus
45
+	replaces = libdbus
46
+
0 47
new file mode 100755
... ...
@@ -0,0 +1,74 @@
1
+# $Id$
2
+# Maintainer: Tom Gundersen <teg@jklm.no>
3
+# Maintainer: Jan de Groot <jgc@archlinux.org>
4
+# Contributor: Link Dupont <link@subpop.net>
5
+# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
6
+
7
+pkgbase=dbus-selinux
8
+pkgname=('dbus-selinux' 'libdbus-selinux')
9
+pkgver=1.10.8
10
+pkgrel=1
11
+pkgdesc="Freedesktop.org message bus system with SELinux support"
12
+url="http://www.freedesktop.org/Software/dbus"
13
+arch=(i686 x86_64)
14
+license=('GPL' 'custom')
15
+groups=('selinux')
16
+makedepends=('libx11' 'systemd-selinux' 'xmlto' 'docbook-xsl' 'audit' 'libselinux')
17
+source=(http://dbus.freedesktop.org/releases/dbus/dbus-$pkgver.tar.gz{,.asc})
18
+md5sums=('e912e930f249454752512aa7ac864d43'
19
+         'SKIP')
20
+validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90'  # Simon McVittie <simon.mcvittie@collabora.co.uk>
21
+              '3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>
22
+
23
+prepare() {
24
+  cd dbus-$pkgver
25
+}
26
+
27
+build() {
28
+  cd dbus-$pkgver
29
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
30
+      --libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=dbus \
31
+      --with-system-pid-file=/run/dbus/pid \
32
+      --with-system-socket=/run/dbus/system_bus_socket \
33
+      --with-console-auth-dir=/run/console/ \
34
+      --enable-inotify \
35
+      --disable-verbose-mode --disable-static \
36
+      --disable-tests --disable-asserts \
37
+      --with-systemdsystemunitdir=/usr/lib/systemd/system \
38
+      --enable-systemd --enable-user-session \
39
+      --enable-selinux --enable-libaudit
40
+  make
41
+}
42
+
43
+package_dbus-selinux(){
44
+  depends=('libdbus-selinux' 'expat' 'audit' 'libselinux' 'libsystemd-selinux')
45
+  optdepends=('libx11: dbus-launch support')
46
+  provides=('dbus-core' "${pkgname/-selinux}=${pkgver}-${pkgrel}" "selinux-${pkgname/-selinux}=${pkgver}-${pkgrel}")
47
+  conflicts=('dbus-core' "${pkgname/-selinux}" "selinux-${pkgname/-selinux}")
48
+  replaces=('dbus-core' "${pkgname/-selinux}")
49
+
50
+  cd dbus-$pkgver
51
+
52
+  # Disable installation of libdbus
53
+  sed -i -e 's/^SUBDIRS = dbus/SUBDIRS =/' Makefile
54
+
55
+  make DESTDIR="$pkgdir" install
56
+
57
+  rm -r "${pkgdir}/var/run"
58
+  rm -r "${pkgdir}/usr/lib/pkgconfig"
59
+
60
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/dbus-selinux/COPYING"
61
+}
62
+
63
+package_libdbus-selinux(){
64
+  pkgdesc="DBus library"
65
+  depends=('libsystemd-selinux')
66
+  provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}")
67
+  conflicts=("${pkgname/-selinux}")
68
+  replaces=("${pkgname/-selinux}")
69
+
70
+  cd dbus-$pkgver
71
+  make DESTDIR="$pkgdir" -C dbus install
72
+  make DESTDIR="$pkgdir" install-data-am
73
+  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/libdbus-selinux/COPYING"
74
+}